lol pov-ray

[Spectere]

Holy crap, I haven't used this program in years:



And the scene file:

Code: [Select]

#declare spSweep = true;
#declare rendSph1 = true;
#declare rendSph2 = true;
#declare rendBGLine = true;

#declare tempTex = texture { pigment { rgb 1 } }
#declare mediaTex =
texture {
pigment { rgbf 1 }
}

#declare sph1Int =
interior {
media {
emission 0.5
density {
gradient z*8

color_map {
[ 0.00 rgb <1,0,1> ]
[ 0.75 rgb <0,0,1> ]
[ 0.95 rgb <1,1,1> ]
}
}
}
}

#declare sph2Int =
interior {
media {
emission 0.2

density {
gradient y
scale <1,5,1>

color_map {
[ 0.00 rgb <0.075, 0.25, 0.50> ]
[ 0.25 rgb <0.125, 0.50, 0.75> ]
[ 0.75 rgb <0.125, 0.50, 0.75> ]
[ 1.00 rgb <0.075, 0.25, 0.50> ]
}
}
}
}

#declare BGLineInt =
interior {
media {
emission 0.125

density {
gradient y
scale <1,5,1>

color_map {
[ 0.00 rgb <0.0, 0.0, 0.5> ]
[ 0.25 rgb <0.0, 0.0, 1.0> ]
[ 0.75 rgb <0.0, 0.0, 1.0> ]
[ 1.00 rgb <0.0, 0.0, 0.5> ]
}
}
}
}

camera {
right 16/10*x
up y
location <0,0,-10>
look_at <0,0,0>
}

light_source {
<5,3,-7.5>, rgb 1
}

#if(rendSph1)
#declare minX = -10;
#declare maxX = 10;
#declare stepX = 0.5;
#declare curX = minX;
#declare scaleX = 2;
#declare scaleY = 3;
 
#if(spSweep)
sphere_sweep {
b_spline, (maxX - minX)/stepX+1
#while(curX < maxX)
<curX, cos(curX/scaleX)*scaleY, 0>, (abs(cos(curX/scaleX)/1.25)+0.5),
#declare curX = curX + stepX;
#end
<maxX*100,0,0>, 0
hollow
texture { mediaTex }
interior { sph1Int }
}
#else
#while(curX < maxX)
sphere {
<curX, cos(curX/scaleX)*scaleY, 0>, (abs(cos(curX/scaleX)/1.25)+0.5)
texture { mediaTex }
interior { sph1Int }
hollow
#declare curX = curX + stepX;
}
#end
#end
#end

#if(rendSph2)
#declare minX = -20;
#declare maxX = 20;
#declare stepX = 0.5;
#declare curX = minX;
#declare scaleX = 2;
#declare scaleY = 3;

#if(spSweep)
sphere_sweep {
b_spline, (maxX - minX)/stepX+1
#while(curX < maxX)
<curX+3, sin(curX/scaleX)*scaleY, 5>, (abs(sin(curX/scaleX)/1.25)+0.5),
#declare curX = curX + stepX;
#end
<maxX*100,0,5>, 0
hollow
texture { mediaTex }
interior { sph2Int }
}
#else
#while(curX < maxX)
sphere {
<curX+3, sin(curX/scaleX)*scaleY, 5>, (abs(sin(curX/scaleX)/1.25)+0.5)
texture { mediaTex }
interior { sph2Int }
hollow
#declare curX = curX + stepX;
}
#end
#end
#end

#if(rendBGLine)
#declare yStep = 2;
#declare yMin = -6;
#declare yMax = 6;
#declare curY = yMin;

#while(curY < yMax)
sphere_sweep {
linear_spline, 3
<-30,curY,10>, 1,
<0,curY,10>,0.75,
<30,curY,10>, 1

texture { mediaTex }
interior { BGLineInt }
hollow
}

#declare curY=curY+yStep;
#end
#end

[Bobbias]

I should learn that stuff... Doesn't seem hard, and maybe I could actually make some cool art that way, lol.